Forum

Code : Tout sélectionner

Notes :
* Saisir chaque proc séparément (et non pas dans un seul fichier comme les séries 3 et +)
* Le programme lanceur est  RPN:  que l'on peut insérer dans le menu de l'organiseur en tapant [MODE] RPN [EXE] dans l'accueil
* Le PEEKW(-24) sert à déterminer le modèle de l'organiseur (utilisé ici pour adapter l'affichage de la pile (variables lim% et ti%) selon si c'est un XP ou un LZ). Pour mon XP c'était 566 mais à chacun de vérifier sur [url]http://archive.psion2.org/org2/cmxplz.htm[/url]
* Touche [haut] : swap ; touche [bas] : drop ; touches [EXE] et [ESPACE] : Enter/Dup ; [ON] : sauver+quitter

RPN:
global pile(50),pp%,lim%,ti%
local i%
cls
print "Init..."
print "Modele : ";
if peek(-24)=566
	mo%="XP" :lim%=2 :ti%=-14
else
	mo%="LZ" :lim%=4 :ti%=-17
endif
print mo%
pp%=0
IF EXIST("RPNDATA")
 open "RPNDATA",a,nb
 first
 while not eof
  ppush:(a.nb)
  next
 endwh
 close
 delete "RPNDATA"
 create "RPNDATA",a,nb
ELSE
 create "RPNDATA",a,nb
ENDIF
-------------------------------------------
RPKB:
local c$(17),d%,e$(1),etat%
c$="" :etat%=1
bclk:: d%=get :e$=chr$(d%)
if loc("+-*/%",e$)>0 and c$<>""
 PPUSH:(val(c$))
endif
if (d%>=%0 and d%<=%9) or e$="."
 c$=c$+e$
 pcmd:: at 1,2 :print ">";c$;" ";
 goto bclk::
elseif d%=13 or d%=32
 if c$=""
  PPUSH:(pile(pp%))
 else
  PPUSH:(val(c$))
 endif
elseif d%=1
 etat%=0
elseif d%=3
 PSWAP:
elseif d%=4
 PDROP:
elseif d%=8
 c$=left$(c$,len(c$)-1)
 goto pcmd::
elseif d%=2
 c$=""
 goto pcmd::
ELSEIF e$="S"
 BEEP 100,800
OFF
elseif e$="+"
 PPUSH:(PPOP:+PPOP:)
elseif e$="*"
 PPUSH:(PPOP:*PPOP:)
elseif e$="-"
 PSWAP:
 PPUSH:(PPOP:-PPOP:)
elseif e$="/"
 if pile(pp%)<>0
  PSWAP:
  PPUSH:(PPOP:/PPOP:)
 else
  beep 400,0.5
 endif
elseif d%=37
 if pile(pp%)<>0
  PPUSH:(1/PPOP:)
 else
  beep 400,0.5
 endif
else
 beep 800,0.5
endif
return etat%
-------------------------------------------
AFFPILE:
local i%
cls :i%=1
while i%<=pp%
 if i%<lim%
  at 1,lim%-i%
  print i%;":";gen$(pile(1+pp%-i%),ti%);
 endif
 i%=i%+1
endwh
-------------------------------------------
PPUSH:(n)
if pp%<50
 pp%=pp%+1
 pile(pp%)=n
else
 beep 400,0.5
endif
-------------------------------------------
PPOP:
if pp%>0
 pp%=pp%-1
 return pile(pp%+1)
else
 beep 400,0.5
endif
-------------------------------------------
PDROP:
local w
w=PPOP:
-------------------------------------------
PSWAP:
local s
if pp%>1
 s=pile(pp%)
 pile(pp%)=pile(pp%-1)
 pile(pp%-1)=s
else
 beep 400,0.5
endif
-------------------------------------------

Code : Tout sélectionner

KEY 1,"LOAD"+CHR$(34)+"DD"+CHR$(34)+":RUN"+CHR$(13)