hp prime et les chaînes

[Céline]

Bonjour,

profitant de mes vacances j'essaie de me familiariser avec la hp prime avec laquelle j'ai beaucoup de mal.

Je tente donc consciencieusement les algorithmes proposés dans ce très bon document.

Lorsque je rentre les instructions suivantes dans le CAS, ça fonctionne :

Code : Tout sélectionner

ch:="123456"
2*expr(ch(3))

ça me renvoie bien 6.

Donc je ne comprends pas pourquoi le programme suivant ne fonctionne pas et me renvoie "type d'argument incorrect".

Code : Tout sélectionner

EXPORT SIRET(n)
BEGIN
LOCAL ch,a,i,s=0;
ch:=STRING(n);
FOR i FROM 1 TO dim(ch) DO
  s:=EXPR(ch(i))+s;
END;
RETURN s;
END

Une explication ?
Merci

[gege]

Bonjour,
expr n'est peut-être pas identique à EXPR ?
C'est un problème endémique sur la Prime, ils ont fait deux modes Home et CAS, avec des ensembles de fonctions différents et le tout est incompréhensible.
C'est vraiment idiot...
G.E.

[charognard]

Salut

Connais pas la prime donc je charge l'émulateur .....

Code : Tout sélectionner

ch:="123456"
2*expr(ch(3))

renvoi une erreur "type d'argument incorrect" et pas 6 comme tu le dis


ch(3) renvoi 51 et pas une chaine !

51 code ASCII de .... 3

CHAR(ch(3)) renvoi "3"
EXPR(CHAR(ch(3))) renvoi 3

Bref il faut mettre un CHAR

[charognard]

Bonjour,
expr n'est peut-être pas identique à EXPR ?
C'est un problème endémique sur la Prime, ils ont fait deux modes Home et CAS, avec des ensembles de fonctions différents et le tout est incompréhensible.
C'est vraiment idiot...
G.E.

Incompréhensible ..... comme ton explication en fait
Salut GÉGÉ
déjà parti

Bref ton programme doit être ça :

Code : Tout sélectionner

EXPORT SIRET(n)
BEGIN
LOCAL ch,i,s=0;
ch:=STRING(n);
FOR i FROM 1 TO dim(ch) DO
  s:=EXPR(CHAR(ch(i)))+s;
END;
RETURN s;
END

[Céline]

Incompréhensible !

Ta solution Charognard fonctionne dans le programme (merci ) mais me renvoie "bad argument value" dans le CAS et pour moi EXPR(ch(3)) fonctionne dans le CAS.

[charognard]

je commence à comprendre GÉGÉ
En fait le résultat de ch(3) diffère ça donne soit 51 soit "3" étonnant !
et bien sur suivant le retour l'erreur ce déclenche.

[tyann]

Bonjour
Si on écrit un code plus standard:

Code : Tout sélectionner

EXPORT SIRET(n)
LOCAL ch,a,i,s;
ch:=STRING(n);
FOR i FROM 1 TO DIM(ch) DO
 s:=EXPR(MID(ch,i,1))+s;
END;
END;

Cela fonctionne dans le CAS et dans Home.

[zpalm]

En mode programme ch(3) renvoie le code ASCII 51, pas la chaine "3". Pour avoir une chaine en mode programme il faut faire ch(3,1). Je ne sais pas pourquoi c’est ainsi mais c’est décrit très brièvement dans le paragraphe “ Références de liste” page 493 du manuel.

Ton programme devrait donc être:

Code : Tout sélectionner

EXPORT SIRET(n)
BEGIN
LOCAL ch,i,s=0;
ch:=STRING(n);
FOR i FROM 1 TO dim(ch) DO
  s:=EXPR(ch(i,1))+s;
END;
RETURN s;
END; 

Une autre façon de faire:

Code : Tout sélectionner

EXPORT SIRET(n)
BEGIN
ΣLIST(ASC(STRING(n))-48);
END; 

[zpalm]

Et le programme complet SIRET du document cité (page 55) peut être MPOisé en:

Code : Tout sélectionner

EXPORT SIRET()
BEGIN
  LOCAL L1,S ;
  INPUT(M,"12 premiers chiffres du SIRET");
  INPUT(N,"2 derniers chiffres du SIRET");
  L1:= ASC(STRING(M)+STRING(N))-48;
  S:= ΣLIST(MAKELIST(ΣLIST(ASC(STRING(L1(I)*(I MOD 2+1)))-48),I,1,14));
  PRINT("Numéro de SIRET "+IFTE(S MOD 10,"in","")+"valide");
END;

[Céline]

Merci à tous

Bonjour
Si on écrit un code plus standard:

Code : Tout sélectionner

EXPORT SIRET(n)
LOCAL ch,a,i,s;
ch:=STRING(n);
FOR i FROM 1 TO DIM(ch) DO
 s:=EXPR(MID(ch,i,1))+s;
END;
END;

Cela fonctionne dans le CAS et dans Home.

En effet c'est beaucoup mieux, c'est le SUB des hp 28 et 48, j'aurais dû y penser. Mais je trouvais cette nouvelle écriture ch(3) intéressante, sans savoir qu'elle ne fonctionnait pas en mode programme comme l'a expliqué zpalm.

Une autre façon de faire:

Code : Tout sélectionner

EXPORT SIRET(n)
BEGIN
ΣLIST(ASC(STRING(n))-48);
END; 

Oui c'est économique mais pas valable dans mon cas car en réalité je veux additionner un chiffre sur deux.

[Céline]

Et le programme complet SIRET du document cité (page 55) peut être MPOisé en:

Code : Tout sélectionner

EXPORT SIRET()
BEGIN
  LOCAL L1,S ;
  INPUT(M,"12 premiers chiffres du SIRET");
  INPUT(N,"2 derniers chiffres du SIRET");
  L1:= ASC(STRING(M)+STRING(N))-48;
  S:= ΣLIST(MAKELIST(ΣLIST(ASC(STRING(L1(I)*(I MOD 2+1)))-48),I,1,14));
  PRINT("Numéro de SIRET "+IFTE(S MOD 10,"in","")+"valide");
END;

Joli