Casio fx 850p

Ici, on fait dans le petit, le LCD qui déchire sa race, on y cause même calculatrices quand on est en manque !

Modérateur : Politburo

Répondre
Avatar du membre
C.Ret
Fonctionne à 9600 bauds
Fonctionne à 9600 bauds
Messages : 3404
Enregistré le : 31 mai 2008 23:43
Localisation : N 49°22 E 6°10

Re: Casio fx 850p

Message par C.Ret »

Voici, une version (sans recherche en profondeur par min-max) utilisable directement sur un SHARP PC-G850V.
L'avantage de ce pocket est que son écran fait 6 ligne de 24 caractères et donc, on peut joueur contre celui-ci sur une grille de 6x6 qui reste affichée tout au long de la partie (pas besoin de recopier).

Code : Tout sélectionner

10:CLEAR :DIM A(5,5),S(1)                          ' A=Grid 6x6   S=Score 0 & 1
12:CLS :LOCATE 19,0:PRINT "You:":LOCATE 19,3:PRINT "Me:"
14:FOR I=0 TO 5:FOR J=0 TO 5:A(I,J)=10+ RND 89:IF A(I,J)>A(L,C) LET L=I,C=J
16:GOSUB 70:NEXT J:NEXT I
18:P=0:GOSUB 80:P=1:GOSUB 80
'
'  User play             S( P=0 )
'
20:I=L,J=C:GOSUB 76
22:GOSUB 74:K= ASC INKEY$ :GOSUB 70:IF K=0 THEN 22  '  animate sel cursor while no key pressed
24:IF K= 4 AND I>0 AND J=C LET I=I-1                '    UP key       = go prev row
26:IF K= 5 AND I<5 AND J=C LET I=I+1                '  DOWN key       = go next row
28:IF K=14 AND I=L AND J<5 LET J=J+1                ' RIGHT key       = go next column
30:IF K=15 AND I=L AND J>0 LET J=J-1                '  LEFT key       = go prev column
32:IF K=23 THEN 40                                  '    BS key       = skip play
34:IF K<>13 AND K<>32 THEN 22                       ' RETURN or SPACE = select position
36:IF A(I,J) GOSUB 78:L=I,C=J,P=0:GOSUB 76:GOSUB 82
'
'  SHARP PC-G850V play   S( P=1 )
'
40:I=L,J=C:GOSUB 78:FOR K=0 TO 5
42:IF A(K,J)>A(L,C) LET L=K,C=J      'Loop-up for greatest value in active column
44:IF A(I,K)>A(L,C) LET L=I,C=K      'Loop-up for greatest value in active row
46:NEXT K
48:GOSUB 74:GOSUB 70:I=I+ SGN (L-I),J=J+ SGN (C-J):IF I<>L OR J<>C THEN 48   'Animate select cursor
50:IF A(L,C) GOSUB 76:P=1:GOSUB 82:GOTO 20    
'
'  End of game
'
52:LOCATE 0,5
54:IF S(0)<S(1) PRINT " I  win  !";
56:IF S(0)=S(1) PRINT "Equality !";
58:IF S(0)>S(1) PRINT "Well done!";
60:INPUT "CONT(Y,N)?";K$:IF LEFT$ (K$,1)<>"N" THEN 12
62:END
'
'  Sub-routines
'             
70:IF A(I,J) THEN T$= "  "+ STR$ A(I,J) ELSE T$="##"                    ' Current 2 digits or ## empty
72:LOCATE 1+3*J,I:PRINT  RIGHT$ (T$,2):RETURN                           ' Display pos value 
74:LOCATE 1+3*J,I:PRINT  "__":RETURN                                    ' Cursor pos __ 
76:LOCATE 3*C,L:PRINT "{":LOCATE 3+3*C,L:PRINT "}":RETURN               ' Active pos markers ON
78:LOCATE 3*C,L:PRINT " ":LOCATE 3+3*C,L:PRINT " ":RETURN               '                    OFF
80:LOCATE 19,1+3*P:PRINT RIGHT$ (" 000"+ STR$ S(P),5):RETURN            'Display score
82:GOSUB 70:IF A(I,J) LET A(I,J)=A(I,J)-1,S(P)=1+S(P):GOSUB 80:GOTO 82  'Animation increasing score
84:RETURN

Evidemment, ce code peut encore être optimisé ou adapté à un affichage diffèrent ce qui nécessitera quelques dispositifs supplémentaires afin de faire défiler la grille pour les systèmes n'ayant pas l'ergonomie du SHARP PC-G850V.
Grille 6x6 sur SHARP PC-G850V.gif
Grille 6x6 sur SHARP PC-G850V.gif (148.54 Kio) Vu 4598 fois
La position en cours de sélection est indiquée par le scintillement du curseur '__' déplacé sur la ligne ou la colonne active à l'aide des touches curseur. On ne peut naviguer que dans la ligne ou la colonne active. La valeur sélectionnée est indiquée en pressant RETURN ou la barre d'ESPACE. Ce qui déclenche une petite animation au cours de laquelle le score est alors incrémenté de la valeur choisie. La touche BS sert à passer son tour et donne donc la main à son adversaire.
Le jeu du pocket donne lieu au déplacement du curseur et à la même animation lors de l'incrémentation de son score.
En fin de partie, entrer Y ou O pour continuer avec une nouvelle grille. Les scores ne sont pas remis à zéro.

P.S.: Pour celles et ceux qui n'auraient pas de SHARP PC-G850V sous la main, je recommande vivement de vous procurer celui proposé par remy dans son excellent PockEmul.
SHARP PC-1211 PC-1360 EL-5150 PC-E500 | Commodore C=128D | Texas Instruments Ti-57LCD Ti-74BASICalc Ti-92II Ti-58c Ti-95PROCalc Ti-30XPROMathPrint | Hewlett-Packard HP-28S HP-41C HP-15C HP-Prime HP-71B | CASIO fx-602p | NUMWORKS | Graphoplex Rietz Neperlog | PockEmul | Sommaire des M.P.O. | Ma...dov'il sapone.
Avatar du membre
C.Ret
Fonctionne à 9600 bauds
Fonctionne à 9600 bauds
Messages : 3404
Enregistré le : 31 mai 2008 23:43
Localisation : N 49°22 E 6°10

Re: Casio fx 850p

Message par C.Ret »

Ce petit jeu, l'air de rien, est très intéressant car c'est un jeu à deux joueurs, à somme nulle et à information complète qui consiste à maximiser les points collectés (ce qui revient à minimiser les pertes car tout ce que l'on ne gagne pas est offert à l'adversaire).

Je suis un peu déçu est triste de voir qu'aucun des amis d'Emile BOREL ou John VON NEUMANN n'ont encore publié ici un perfectionnement de nos codes(*) où le pocket joue un peu mieux en appliquant un des principes fondamentaux de la théorie des jeux, à savoir en appliquant au pire une stratégie à somme nulle, à l'aide d'un algorithme minimax.

Je suis désolé de constater que sur un forum épris de vieilleries programmables et de jeux vidéo, il n'y ai aucun adepte de l'équilibre de Nash !
Image


(*)
viewtopic.php?p=562618#p562618
viewtopic.php?p=562478#p562478
Modifié en dernier par C.Ret le 11 déc. 2021 09:26, modifié 3 fois.
SHARP PC-1211 PC-1360 EL-5150 PC-E500 | Commodore C=128D | Texas Instruments Ti-57LCD Ti-74BASICalc Ti-92II Ti-58c Ti-95PROCalc Ti-30XPROMathPrint | Hewlett-Packard HP-28S HP-41C HP-15C HP-Prime HP-71B | CASIO fx-602p | NUMWORKS | Graphoplex Rietz Neperlog | PockEmul | Sommaire des M.P.O. | Ma...dov'il sapone.
Avatar du membre
badaze
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 8384
Enregistré le : 12 févr. 2007 18:36
Localisation : Pas très loin de Lyon
Contact :

Re: Casio fx 850p

Message par badaze »

C.Ret a écrit : 11 déc. 2021 09:19 Ce petit jeu, l'air de rien, est très intéressant car c'est un jeu à deux joueur à somme nulle et à information complète qui consiste à maximisier les points collectés (ce qui revient à minimiser les pertes car tout ce que l'on ne gagne pas est offert à l'adversaire).

Je suis un peu déçu est triste de voir qu'aucun des amis d'Emile BOREL ou John VON NEUMANN n'ont encore publié aussi un perfectionnement de nos code où le pocket joue un peu mieux en appliquant un des principes fondamentaux de la théorie des jeux, à savoir en appliquant au mieux une stratégie à somme nulle (et en mieux une stratégie gagnante) à l'aide d'un algorithme minimax.

Je suis désolé de constater que sur un forum épris de vieilleries programmables et de jeux vidéo, il n'y ai aucun adepte de l'équilibre de Nash !
Image
minimax et maximin …
Ça réveille de vieux souvenirs d’université !
Tout est bon dans le pocket.
Moi j'aime tout.... Casio, HP, Sharp, TI et les autres sauf que les TI semblent ne pas m'aimer :(
http://www.emmella.fr
Mes Casio - HP - Sharp - TI
Homme invisible.
Avatar du membre
C.Ret
Fonctionne à 9600 bauds
Fonctionne à 9600 bauds
Messages : 3404
Enregistré le : 31 mai 2008 23:43
Localisation : N 49°22 E 6°10

Re: Casio fx 850p

Message par C.Ret »

:) Ah! Ah!

Je savais bien qu'il y a sur Silicium des amis cultivés et instruits ! Ca me réchauffe le cœur de voir que toutes ces choses liées à la Théorie de Jeux n'est pas morte. C'est une facette non négligeable de notre culture vidéo-ludique ...

Non mais des fois... ;)
SHARP PC-1211 PC-1360 EL-5150 PC-E500 | Commodore C=128D | Texas Instruments Ti-57LCD Ti-74BASICalc Ti-92II Ti-58c Ti-95PROCalc Ti-30XPROMathPrint | Hewlett-Packard HP-28S HP-41C HP-15C HP-Prime HP-71B | CASIO fx-602p | NUMWORKS | Graphoplex Rietz Neperlog | PockEmul | Sommaire des M.P.O. | Ma...dov'il sapone.
Avatar du membre
Marge
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 6172
Enregistré le : 01 oct. 2008 14:39
Localisation : En bas, tout au fond à gauche.

Re: Casio fx 850p

Message par Marge »

C.Ret a écrit : 11 déc. 2021 09:30 :) Ah! Ah!

Je savais bien qu'il y a sur Silicium des amis cultivés et instruits ! Ca me réchauffe le cœur de voir que toutes ces choses liées à la Théorie de Jeux n'est pas morte. C'est une facette non négligeable de notre culture vidéo-ludique ...

Non mais des fois... ;)
Ce n’est pas faute de m’y être intéressé, j’ai pas mal lu sur le sujet, mais par manque de pédagogie ou erreur de câblage interne, je n’ai jamais rien compris au Minimax ni à l’équilibre de Nash ! Alors si tu as un ou deux liens intéressants sur le thème, C.Ret, ou si tu veux bien calmement m’expliquer tout cela quand nous nous verrons, je promets de faire un effort...

PS: j’ai déjà commencé par chercher d’où vient ce graphe ; mais rien à voir avec la choucroute ! D’accord, j’exagère... ;) L’économie, je l’ai aussi lu, s’inspire beaucoup de la théorie des jeux. Il me reste à revenir de l’économie au jeu, hein, j’ai bon, là ?
:D
3 hommes, 3 demis, un 3a... Magnéto, Serge !

Quelques-uns de mes petits programmes pour machines Hewlett-Packard :
15C : Knight's Tour ;
29C : (k-)Permutations, Combinations, Linear Regression and Pseudo-random number ;
34C : Hanoi Towers - Automatic & Manual resolutions ;
67
__: A L I E N .

« Boris », c'était juste Maurice enrhumé.
Andromede
Fonctionne à 300 bauds
Fonctionne à 300 bauds
Messages : 157
Enregistré le : 09 oct. 2021 15:15

Re: Casio fx 850p

Message par Andromede »

Bonsoir,
Je suis vraiment très content de faire partie de ce forum. Je suis fasciné par ce niveau élevé de connaissance. C.Ret a activé nos neurones endormies. Je me suis mis à reprendre des concepts et principes intéressants et nécessaires pour la suite comme la théorie des jeux. Je propose qu'on documente le problème une fois celui-ci totalement résolu et optimisé et ce sous la forme d'un guide pédagogique qui reprend toutes les étapes réalisées pour solutionner le problème avec un rappel de tous les concepts, principes, théories et algorthmes ayant été utilisés. Ce guide sera ensuite inséré comme pièce jointe afin de servir de mémoire structurant tout notre travail.
Pour ma part, je travaille actuellement sur le code de C.Ret que je trouve très intéressant.
Casio FX-850P, FX-880P, FX-7000G, FX-7000GA, FX-3900P
Canon X-07
Sharp E500, EL-9000, PC 1500
Texas Instruments TI-57 II, TI-62 Galaxy, TI-66 Programmable, TI-74 Basicalc, TI-74S, TI-95 Procalc
" Les machines un jour pourront résoudre tous les problèmes, mais jamais aucune d'entre elles ne pourra en poser un !" Albert Einstein
Avatar du membre
Marge
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 6172
Enregistré le : 01 oct. 2008 14:39
Localisation : En bas, tout au fond à gauche.

Re: Casio fx 850p

Message par Marge »

Andromede a écrit : 14 déc. 2021 20:24 Bonsoir,
Je suis vraiment très content de faire partie de ce forum. Je suis fasciné par ce niveau élevé de connaissance. C.Ret a activé nos neurones endormies. [...]
Il y a d'autres candidats un peu moins présents mais tout aussi intéressants ; cela dit, moi aussi je me réjouis grandement de la présence de C.Ret parmi nous.
Je propose qu'on documente le problème une fois celui-ci totalement résolu et optimisé [...].
La solution que tu proposes s'apparente à un fil dédié (pourquoi pas ?) ou à un article pour la Gazette dans le style de ChocolatCroissant tel que le dossier courant sur plusieurs épisodes au sujet de la TI-57 - qu'on doit fortement recommander.

Mais c'est du travail, et j'ai l'impression que la somme de labeur demandée dépassera toutes les velléités des contributeurs éventuels. Relèveras-tu le gant ?
3 hommes, 3 demis, un 3a... Magnéto, Serge !

Quelques-uns de mes petits programmes pour machines Hewlett-Packard :
15C : Knight's Tour ;
29C : (k-)Permutations, Combinations, Linear Regression and Pseudo-random number ;
34C : Hanoi Towers - Automatic & Manual resolutions ;
67
__: A L I E N .

« Boris », c'était juste Maurice enrhumé.
Andromede
Fonctionne à 300 bauds
Fonctionne à 300 bauds
Messages : 157
Enregistré le : 09 oct. 2021 15:15

Re: Casio fx 850p

Message par Andromede »

Bonsoir,
J'ai mis du temps pour cerner toute la logique du jeu. Le code ci-après fonctionne très bien. Je ne me suis pas intéressé à faire un code propre pour le moment car mon objectif premier était d'arriver à coder cette logique avec le BASIC et la mémoire (à 4 ko) limités de mon CASIO FX 850P sans pour autant m'éloigner de la logique utilisée dans le N°20 de l'ORDINATEUR DE POCHE (Janvier - Février 1984 / Page 37) . C'est très loin des capacités du SHARP PC G850V utilisé par C.Ret et que je salue au passage pour sa solution plus intéressante pour plusieurs raisons et sur laquelle je reviendrais dans une autre discussion. L'essentiel pour l'instant étant de résoudre le problème en prenant en charge un maximum de scénarios et de tests de contrôle des choix effectués par les joueurs avant de réfléchir à l'optimisation.

Code : Tout sélectionner

5 SCORE1=0: SCORE2=0: C1=1: L1=1: C2=1: L2=1: M=0: R$="": MAX=0
10 CLS
20 DIM TB(25)
30 FOR I=0 TO 24
40 TB(I)=INT(RAN#*9)+1
50 NEXT I
60 I=0
70 FOR L=1 TO 5
80 FOR C=1 TO 5
90 LOCATE 5+C*3,L-1:PRINT TB(I);
100 I=I+1
110 NEXT C
120 FOR A=1 TO 2000: NEXT A
130 NEXT L
140 PRINT: INPUT"VOULEZ-VOUS COMMENCER:Y/N?", R$
150 IF R$="Y" THEN GOTO 1000
160 IF R$+"N" THEN GOTO 2000
170 GOTO 140
1000 INPUT "COL?",C1
1010 IF C1<1 OR C1>5 THEN GOTO 1000
1020 INPUT"LIG?",L1
1030 IF L1<1 OR L1>5 THEN GOTO 1020
1040 I=5*L1+C1-6
1050 SCORE1=SCORE1+TB(I)
1060 TB(I)=0
1070 M=M+1
2000 FOR I=1 TO 5
2010 IF TB(5*L1+I-6)>MAX THEN MAX=TB(5*L1+I-6): C2=I: L2=L1
2020 NEXT I
2030 FOR I=1 TO 5
2040 IF TB(5*I+C1-6)>MAX THEN MAX=TB(5*I+C1-6): C2=C1: L2=I
2050 NEXT I
2060 PRINT"COL:"C2 "LIG:"L2
2080 SCORE2=SCORE2+TB(5*L2+C2-6)
2090 TB(5*L2+C2-6)=0
2100 M=M+1
2110 IF M>24 OR MAX=0 THEN GOTO 3000
2120 MAX=0
2200 FOR I=1 TO 5
2210 IF TB(5*L2+I-6)>MAX THEN MAX=TB(5*L2+I-6)
2220 NEXT I
2230 FOR I=1 TO 5
2240 IF TB(5*I+C2-6)>MAX THEN MAX=TB(5*I+C2-6)
2250 NEXT I
2260 IF MAX=0 THEN GOTO 3000
2510 INPUT "COL?", C1
2520 IF C1<1 OR C1>5 THEN GOTO 2510
2530 INPUT "LIG?",L1
2540 IF L1<1 OR L1>5 THEN GOTO 2530
2550 IF L1<>L2 AND C1<>C2 THEN PRINT"IMPOSSIBLE!": GOTO 2510
2560 IF TB(5*L1+C1-6)=0 THEN PRINT "CASE DEJA JOUEE!": GOTO 2510
2570 SCORE1=SCORE1+TB(5*L1+C1-6)
2580 TB(5*L1+C1-6)=0
2590 M=M+1
2600 IF M>24 THEN GOTO 3000
2610 MAX+0
2620 GOTO 2000
3000 PRINT "ORDINATEUR:"SCORE2 "VOUS:"SCORE1:END
Bien sûr, une fois le code simplifié, optimisé et bien nettoyé, il sera beaucoup plus léger et plus esthétique que ça. Par la suite j'implémenterai des animations comme l'a proposé C.Ret pour assurer un minimum de confort et d'ergonomie au jeu. Cependant, le travail de réflexion et de recherche n'est pas encore achevé. Pourquoi :?: Parce que tout simplement je gagne à tous les coups. Autrement dit, comment faire pour que le Pocket Computer devienne redoutable sur ce jeu ? Comment donc améliorer le choix quand c'est à l'ordinateur de jouer ? 8O
C.Ret nous a éclairé en nous indiquant la piste de l'algorithme MIN-MAX. :| :idea:
Modifié en dernier par Andromede le 01 janv. 2022 16:00, modifié 2 fois.
Casio FX-850P, FX-880P, FX-7000G, FX-7000GA, FX-3900P
Canon X-07
Sharp E500, EL-9000, PC 1500
Texas Instruments TI-57 II, TI-62 Galaxy, TI-66 Programmable, TI-74 Basicalc, TI-74S, TI-95 Procalc
" Les machines un jour pourront résoudre tous les problèmes, mais jamais aucune d'entre elles ne pourra en poser un !" Albert Einstein
Andromede
Fonctionne à 300 bauds
Fonctionne à 300 bauds
Messages : 157
Enregistré le : 09 oct. 2021 15:15

Re: Casio fx 850p

Message par Andromede »

Bonjour et meilleurs vœux de bonheur et santé à toutes et à tous :D
Casio FX-850P, FX-880P, FX-7000G, FX-7000GA, FX-3900P
Canon X-07
Sharp E500, EL-9000, PC 1500
Texas Instruments TI-57 II, TI-62 Galaxy, TI-66 Programmable, TI-74 Basicalc, TI-74S, TI-95 Procalc
" Les machines un jour pourront résoudre tous les problèmes, mais jamais aucune d'entre elles ne pourra en poser un !" Albert Einstein
Andromede
Fonctionne à 300 bauds
Fonctionne à 300 bauds
Messages : 157
Enregistré le : 09 oct. 2021 15:15

Re: Casio fx 850p

Message par Andromede »

Bonjour,
En me documentant sur le CASIO FX 850P, j'ai trouvé qu'il est capable d'utiliser un tableau à plusieurs dimensions. J'ai donc modifié le code en travaillant sur un tableau à deux dimensions au lieu d'un tableau à une dimension tel que publié précédemment.

Code : Tout sélectionner

1 SCORE1=0: SCORE2=0:X1=0:Y1=0:X2=0:Y2=0:M=0:MAX=0
10 CLS
20 DIM TB(5,5)
30 FOR X=0 TO 4
40 FOR Y=0 TO 4
50 TB(X,Y)=INT(RAN#*9)+1
60 LOCATE 5+(Y+1)*3,X: PRINT TB(X,Y);
70 NEXT Y
80 FOR I=0 TO 2000: NEXT I
90 NEXT X
200 PRINT: INPUT "VOULEZ-VOUS COMMENCER: Y/N?", R$
210 IF R$="Y" THEN GOTO 2200
220 IF R$="N" THEN GOTO 2000
230 GOTO 200
2000 FOR Y=0 TO 4
2010 IF TB(X1,Y)>MAX THEN MAX=TB(X1,Y): X2=X1: Y2:Y
2020 NEXT Y
2030 FOR X=0 TO 4
2040 IF TB(X,Y1)>MAX THEN MAX=TB(X,Y1): X2=X: Y2=Y1
2050 NEXT X
2060 PRINT "COL:"Y2 "LIG:"X2
2070 SCORE2=SCORE2+TB(X2,Y2)
2080 TB(X2,Y2)=0
2090 M=M+1
2100 IF M>24 OR MAX=0 THEN GOTO 3000
2110 MAX=0
2200 FOR Y=0 TO 4
2210 IF TB(X2,Y)>MAX THEN MAX=TB(X2,Y)
2220 NEXT Y
2230 FOR X=0 TO 4
2240 IF TB(X,Y2)>MAX THEN MAX=TB(X,Y2)
2250 NEXT X
2260 IF MAX=0 THEN GOTO 3000
2500 INPUT "COL?", Y1
2510 IF Y1<0 OR Y1>5 THEN GOTO 2500
2520 INPUT "LIG?",X1
2530 IF X1<0 OR X1>5 THEN GOTO 2520
2540 IF X1<>X2 AND Y1<>Y2 THEN PRINT "COUP IMPOSSIBLE!": GOTO 2500
2550 IF TB(X1,Y1)=0 THEN PRINT "CASE DEJA JOUEE!": GOTO 2500
2560 SCORE1=SCORE1+TB(X1,Y1)
2570 TB(X1,Y1)=0
2580 M=M+1
2590 IF M>24 THEN GOTO 3000
2600 MAX=0
2610 GOTO 2000
3000 PRINT "ORDINATEUR:"SCORE2;
3010 PRINT "VOUS:"SCORE1;
3020 END
Casio FX-850P, FX-880P, FX-7000G, FX-7000GA, FX-3900P
Canon X-07
Sharp E500, EL-9000, PC 1500
Texas Instruments TI-57 II, TI-62 Galaxy, TI-66 Programmable, TI-74 Basicalc, TI-74S, TI-95 Procalc
" Les machines un jour pourront résoudre tous les problèmes, mais jamais aucune d'entre elles ne pourra en poser un !" Albert Einstein
Avatar du membre
ledudu
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 5631
Enregistré le : 26 mars 2009 13:07
Localisation : Ile de France
Contact :

Re: Casio fx 850p

Message par ledudu »

Image
Avatar du membre
bernouilli92
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 5226
Enregistré le : 21 nov. 2012 13:03
Localisation : Ile de France

Re: Casio fx 850p

Message par bernouilli92 »

Eh ben. Et toutes en boîtes!
HP, Casio, Sharp, Psion, quelques TI et divers autres
Avatar du membre
ledudu
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 5631
Enregistré le : 26 mars 2009 13:07
Localisation : Ile de France
Contact :

Re: Casio fx 850p

Message par ledudu »

bernouilli92 a écrit : 01 janv. 2022 21:48 Eh ben. Et toutes en boîtes!
Image
Il me manque la boite du VX-1... :oops:
Andromede
Fonctionne à 300 bauds
Fonctionne à 300 bauds
Messages : 157
Enregistré le : 09 oct. 2021 15:15

Re: Casio fx 850p

Message par Andromede »

Waouuu!!!!!!!!! C'est la caverne d'Ali Baba :D 8O
Casio FX-850P, FX-880P, FX-7000G, FX-7000GA, FX-3900P
Canon X-07
Sharp E500, EL-9000, PC 1500
Texas Instruments TI-57 II, TI-62 Galaxy, TI-66 Programmable, TI-74 Basicalc, TI-74S, TI-95 Procalc
" Les machines un jour pourront résoudre tous les problèmes, mais jamais aucune d'entre elles ne pourra en poser un !" Albert Einstein
Avatar du membre
phm
Fonctionne à 2400 bauds
Fonctionne à 2400 bauds
Messages : 1361
Enregistré le : 08 avr. 2016 18:36
Localisation : Est Parisien

Re: Casio fx 850p

Message par phm »

Andromede a écrit : 02 janv. 2022 08:03 Waouuu!!!!!!!!! C'est la caverne d'Ali Baba :D 8O
Seulement les boites sont vides :mrgreen:
:arrow: :arrow: :arrow:
HEWLETT-PACKARD : The best
CANON
X-07 X-730 X-711 XR-100 XM-101 XP-110F XP-120F XP-130F XP-140

AMSTRAD CPC-464 CPC-6128 ATARI STF DAI Indata
Répondre

Retourner vers « Tous les Pockets »