Je reviens après quelques soucis de santé.
Merci pour la proposition de transformer mes lignes en .wav
Voici les 3/4 du PRGM
[edit modo] Utiliser la balise Code [/edit modo]
Code : Tout sélectionner
15:CLEAR:RESTORE:RADIAN:WAIT 50:USING
20:F1$="####.####":F2$="###.###":F3$="###.#"
25:R1=PI/180:K=0.01720209895
30:"M":PRINT"MENU DES RESULTATS"
35:PRINT "1 = Coor.Astrometriques":PRINT "2 = Coor.Horizontales":PRINT "3 = Tous resultats"
40:INPUT "Votre choix ? 1,2 ou 3 ";FL:PRINT "Choix du menu: "; STR$ (FL)
45:IF FL=1 GOTO 65
50:"L":PRINT "LIEU D OBSERVATION":USING F1$
55:INPUT "LATITUDE (d.ms) ? ";LA:PRINT "Lat.(d.ms) =";LA:LA=DEG LA*R1
60:INPUT "LONGITUDE (d.ms) ? ";LO:PRINT "Long.(d.ms) =";Lo:Lo=DEG Lo*R1
65:"S":PRINT:INPUT "Nom comete ou asteroide ? ";SS$:PRINT"** ";SS$;" **"
70:IF FL=2 LET AA=1950 GOTO 80
75:INPUT "EQUINOXE 1950 ou 2000 ? ";AA
80:RESTORE LEFT$ (SS$,3)
85:READ J9,F9,Q,EX,W,N,I,M1,M2
90:W=W*R1:N=N*R1:I=I*R1
95:REM P"S ET Q"S
100:E=23.4457859*R1
105:W1=SIN W;W2=COS W
110:N1=SIN N;N2=COS N
115:I1=SIN I;I2=COS I
120:E1=SIN E;E2=COS E
125:P7=W2*N2-W1*N1*I2:PP=W2*N1+W1*N2*I2
130:P8=PP*E2-W1*I1*E1
135:P9=PP*E1+W1*I1*E2
140:Q7=-W1*N2-W2*N1*I2:QQ=W2*N2*I2-W1*N1
145:Q8=QQ*E2-W2*I1*E1
150:Q9=QQ*E1+W2*I1*E2
155:"D":WAIT 20: PRINT:INPUT "JOUR ? ";D:INPUT "MOIS ? ";M:INPUT "ANNEE ? ";Y
160:MM=M:AN=Y
165:WAIT 120 PRINT "DATE = ";STR$ D+"-"+STR$M+"-"+STR$ Y
170 GOSUB 800
175:J1=J:F1=F:T0=J-2415020:T0=(T0+F)/36525
180:"H":IF FL=1 LET HE=0:GOTO 190
185:INPUT "HEURE TU(h.ms) ? ";HE:USING F1$:PRINT "Heure TU(h.ms)=";HE
190:HE=DEG HE/24:F2=F1+HE:J2=J1+(F2>1):F2=F2-(F2>1)
195:GOTO 500
200:T=(J2-J9)+(F2-F9)
205:GOSUB 600
210 REM POSITION DANS LE PLAN DE L ORBITE.
215:X1=R*COS V:Y1=R*SIN V
220:REM COORDONNEES EQUATORIALES HELIO.
225:X2=P7*X1+Q7*Y1
230:Y2=P8*X1+Q8*Y1
235:Z2=P9*X1+Q9*Y1
240:REM COORDONNEES EQUATORIALES GEO.
245:X3=X+X2:Y3=Y+Y2:Z3=Z+Z2
250:IF AA=2000 GOSUB 440
255:D3=SQR(X3*X3+Y3*Y3+Z3*Z3)
260:D4=SQR(X*X+Y*Y+Z*Z)
265:EL=ACS((D3*D3+D4*D4-R*R)/(2*D3*D4))
266:M3=M1:M4=M2:IF JD>2446470.95 AND LEFT$(SS$,3)="HAL" LET M3=4.94:M4=7.68
267:MA=M3+5*LOG D3+M4*LOG R
270:A=ATN (Y3/X3)+3.1415927*(X3<0):A=A+2*3.1415927*(A<0):G0=A
275:D=ATN (Z3/SQR(X3*X3+Y3*Y3)):H0=D
280:IF FL=2 GOTO 320
285:USING:PRINT "EQUINOXE DE : "; AA
290:USING F1$:PRINT "ASCENSION DROITE " ;DMS
295:PRINT: "DEC.(d.ms)=";DMS(D/R1)
300:USING F2$: PRINT "Dist.Geo(UA) ="; D3
305:PRINT "Dist.Helio (UA)= "; R
310:USING F3$:PRINT "Elong.(deg) =";EL/R1
312:IF M1<>0 PRINT "Magnitude" ="; MA
315:IF FL=1 GOTO 415
320:REM PASSAGE EQUINOXE STANDARD ---> EQUINOXE SE LA DATE
325:DT=AN+MM/12-AA
330:G1=G0+0.0002234748*DT+0.0000971566*SIN G0*TAN H0*DT
335:H1=H0+0.0000971566*DT*COS G0
340:REM TEMPS SIDERAL
345:TS=0.27691938+100.0021359*T0+0.000001075*T0*T0:TS=TS-INT TS
350 :TG=2*3.141597*TS-LO :TG=TG+2*3.141527*(TG<0) :TS=TG+6.30038809*HE:TS=TS-2*3.1415927*5TS>2*3.1415927)
355:REM AZIMUT & SITE
360:HR=TS-G1
365:P=COS HR*SIN LA-TAN H1*COS LA
370 :AZ=ATN(SIN HR/P)+3.1415927*(P<0)
375:IF AZ<0 LET AZ=AZ+2*3.1415927
380:SI=ASN(SIN LA*SIN H1+COS LA*COS H1*COS HR)
385 :IF SI>0.17 LET SI=SI+0.1540*(3.1415927/2-SI-ASN(0.998115*CO SI))
390 : PRINT "EQUINOXE DE LA DATE”
395 :USING F1$ : PRINT "ASC.(h.ms) =”;DMS(G1/15/R1)
400: PRINT " DEC.(d.ms) =”;DMS(H1/R1)
405: PRINT " AZIMUT.(d.ms) =”;DMS(AZ/R1)
410: PRINT " SITE.(d.ms) =”;DMS(SI/R1)
415 :PAUSE "AUTRE (Astres=S ,Date=D,Heure=H,FIN=F) ? "
416 :Q1$=INKEY$
420 :IF Q1$= "D" GOTO "D"
425 :IF Q1$= "H" GOTO "H"
430 :IF Q1$= "S" GOTO "S"
435 :IF Q1$= "F" USING:DEGREE:GOTO 437
436:IF ASC Q1$=0 GOTO 415
437:ENDGilbert
